factor-work/bonerbonerboner/actions/actions.factor

USING: kernel furnace.actions sequences validators accessors html.forms http.server.responses http.server.dispatchers formatting assocs ;
USING: bonerbonerboner.dns ;

IN: bonerbonerboner.actions

TUPLE: bbb-dispatcher < dispatcher ;

: v-valid-subdomain ( str -- subdomain )
    dup get-subdomains member? [ "not a valid subdomain" throw ] unless ;

: validate-subdomain ( -- )
    {
        { "name" [ v-required v-valid-subdomain ] }
    } validate-params ;

: <subdomain-action> ( -- action )
    <page-action>
    [
        validate-subdomain
        "name" value "subdomain" set-value
    ] >>init
    { bbb-dispatcher "subdomains" } >>template ;

: <404-subdomain-action> ( -- action )
    <page-action>
    [ "_404" "subdomain" set-value ] >>init
    { bbb-dispatcher "subdomains" } >>template ;

: <heartbeat-action> ( -- action )
    <action> [ "bonerbonerboner" <text-content> ] >>display ;

TUPLE: subdomain-link subdomain url ;

: get-subdomain-links ( -- subdomain-links )
    get-subdomains [ "bbb" = ] reject
    [ first dup "https://%s.bonerbonerboner.com" sprintf subdomain-link boa ] map ;


: <meta-action> ( -- action )
    <page-action>
    [
        get-subdomain-links "subdomains" set-value
    ] >>init
    { bbb-dispatcher "meta" } >>template ;