factor/core/sets/sets.factor

172 lines
3.7 KiB
Factor
Raw Normal View History

2010-02-26 16:01:01 -05:00
! Copyright (C) 2010 Daniel Ehrenberg
! See http://factorcode.org/license.txt for BSD license.
USING: assocs hashtables kernel math sequences vectors ;
IN: sets
! Set protocol
MIXIN: set
2010-02-26 16:01:01 -05:00
GENERIC: adjoin ( elt set -- )
2013-03-23 19:56:35 -04:00
GENERIC: ?adjoin ( elt set -- ? )
2010-02-26 16:01:01 -05:00
GENERIC: in? ( elt set -- ? )
GENERIC: delete ( elt set -- )
GENERIC: ?delete ( elt set -- ? )
2010-02-26 16:01:01 -05:00
GENERIC: set-like ( set exemplar -- set' )
GENERIC: fast-set ( set -- set' )
GENERIC: members ( set -- seq )
2010-02-26 16:01:01 -05:00
GENERIC: union ( set1 set2 -- set )
GENERIC: intersect ( set1 set2 -- set )
GENERIC: intersects? ( set1 set2 -- ? )
GENERIC: diff ( set1 set2 -- set )
GENERIC: subset? ( set1 set2 -- ? )
GENERIC: set= ( set1 set2 -- ? )
2010-02-27 00:27:40 -05:00
GENERIC: duplicates ( set -- seq )
2010-02-26 16:01:01 -05:00
GENERIC: all-unique? ( set -- ? )
GENERIC: null? ( set -- ? )
2010-12-27 22:22:36 -05:00
GENERIC: cardinality ( set -- n )
2013-03-07 21:48:15 -05:00
GENERIC: clear-set ( set -- )
2010-12-27 22:22:36 -05:00
2013-03-23 17:46:54 -04:00
M: f members drop f ;
2010-12-27 22:22:36 -05:00
M: f cardinality drop 0 ;
2010-02-26 16:01:01 -05:00
2013-03-09 01:26:56 -05:00
M: f delete 2drop ;
2013-03-07 21:48:15 -05:00
M: f clear-set drop ; inline
2010-02-26 16:01:01 -05:00
! Defaults for some methods.
! Override them for efficiency
M: set ?adjoin 2dup in? [ 2drop f ] [ adjoin t ] if ;
2013-03-23 19:56:35 -04:00
M: set ?delete 2dup in? [ delete t ] [ 2drop f ] if ;
M: set null? cardinality 0 = ; inline
M: set cardinality members length ;
2010-12-27 22:22:36 -05:00
M: set clear-set [ members ] keep [ delete ] curry each ;
2013-03-07 21:48:15 -05:00
M: set set-like drop ; inline
2010-02-27 00:27:40 -05:00
<PRIVATE
: ?members ( set -- seq )
dup sequence? [ members ] unless ; inline
: (union) ( set1 set2 -- seq )
[ ?members ] bi@ append ; inline
PRIVATE>
M: set union [ (union) ] keep set-like ;
2008-05-25 20:44:37 -04:00
2010-02-26 16:01:01 -05:00
<PRIVATE
2010-02-26 16:01:01 -05:00
: tester ( set -- quot )
fast-set [ in? ] curry ; inline
2008-05-25 20:44:37 -04:00
2010-02-26 16:01:01 -05:00
: sequence/tester ( set1 set2 -- set1' quot )
[ members ] [ tester ] bi* ; inline
: small/large ( set1 set2 -- set1' set2' )
2013-03-26 18:49:37 -04:00
2dup [ cardinality ] bi@ > [ swap ] when ; inline
: (intersect) ( set1 set2 -- seq )
small/large sequence/tester filter ; inline
: (diff) ( set1 set2 -- seq )
2017-01-06 17:08:42 -05:00
sequence/tester reject ; inline
2010-02-26 16:01:01 -05:00
PRIVATE>
M: set intersect [ (intersect) ] keep set-like ;
M: set diff [ (diff) ] keep set-like ;
M: set intersects?
small/large sequence/tester any? ;
2010-02-26 16:01:01 -05:00
<PRIVATE
: (subset?) ( set1 set2 -- ? )
sequence/tester all? ; inline
PRIVATE>
M: set subset?
2dup [ cardinality ] bi@ > [ 2drop f ] [ (subset?) ] if ;
2010-12-27 22:22:36 -05:00
M: set set=
2dup [ cardinality ] bi@ = [ (subset?) ] [ 2drop f ] if ;
M: set fast-set ;
M: set duplicates drop f ;
2010-02-26 16:01:01 -05:00
M: set all-unique? drop t ;
2010-02-26 16:01:01 -05:00
! Sequences are sets
INSTANCE: sequence set
2010-02-26 16:01:01 -05:00
M: sequence in?
member? ; inline
2010-02-26 16:01:01 -05:00
M: sequence adjoin
[ delete ] [ push ] 2bi ;
2010-02-26 16:01:01 -05:00
M: sequence delete
remove! drop ; inline
2010-02-26 16:01:01 -05:00
M: sequence set-like
[ members ] dip like ;
2010-02-26 16:01:01 -05:00
M: sequence members
2017-02-07 17:50:58 -05:00
f fast-set [ ?adjoin ] curry filter ;
2010-12-27 22:22:36 -05:00
M: sequence null?
empty? ; inline
2010-02-26 16:01:01 -05:00
2010-12-27 22:22:36 -05:00
M: sequence cardinality
fast-set cardinality ;
2010-12-27 22:22:36 -05:00
2013-03-07 21:48:15 -05:00
M: sequence clear-set
delete-all ; inline
2011-09-17 11:11:48 -04:00
: combine ( sets -- set/f )
[ f ]
[ [ [ ?members ] map concat ] [ first ] bi set-like ]
if-empty ;
2010-02-26 16:01:01 -05:00
2013-03-08 10:57:45 -05:00
: intersection ( sets -- set/f )
[ f ] [ [ ] [ intersect ] map-reduce ] if-empty ;
: refine ( sets -- set/f )
[ f ] [ [ ] [ intersect ] map-reduce ] if-empty ;
2011-09-22 20:19:51 -04:00
: gather ( ... seq quot: ( ... elt -- ... elt' ) -- ... newseq )
2010-02-26 16:01:01 -05:00
map concat members ; inline
: adjoin-at ( value key assoc -- )
[ [ f fast-set ] unless* [ adjoin ] keep ] change-at ;
: within ( seq set -- subseq )
2011-10-14 13:23:52 -04:00
tester filter ;
: without ( seq set -- subseq )
2017-01-06 17:08:42 -05:00
tester reject ;
2013-03-10 12:11:05 -04:00
: adjoin-all ( seq set -- )
[ adjoin ] curry each ;
2013-03-08 10:57:45 -05:00
: union! ( set1 set2 -- set1 )
2013-03-10 12:11:05 -04:00
?members over adjoin-all ;
2013-03-08 10:57:45 -05:00
2013-03-08 11:21:16 -05:00
: diff! ( set1 set2 -- set1 )
dupd sequence/tester [ dup ] prepose pick
[ delete ] curry [ [ drop ] if ] curry compose each ;
2013-03-24 19:48:45 -04:00
: intersect! ( set1 set2 -- set1 )
dupd sequence/tester [ dup ] prepose [ not ] compose pick
[ delete ] curry [ [ drop ] if ] curry compose each ;