factor/library/httpd/httpd.factor

! :folding=indent:collapseFolds=1:

! $Id$
!
! Copyright (C) 2003, 2004 Slava Pestov.
! 
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions are met:
! 
! 1. Redistributions of source code must retain the above copyright notice,
!    this list of conditions and the following disclaimer.
! 
! 2. Redistributions in binary form must reproduce the above copyright notice,
!    this list of conditions and the following disclaimer in the documentation
!    and/or other materials provided with the distribution.
! 
! THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES,
! INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
! FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! DEVELOPERS AND CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
! SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
! PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
! OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
! WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
! OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
! ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

IN: httpd
USE: arithmetic
USE: combinators
USE: errors
USE: kernel
USE: lists
USE: logging
USE: logic
USE: namespaces
USE: stack
USE: stdio
USE: streams
USE: strings

USE: httpd-responder
USE: url-encoding

: bad-request ( -- )
    "400 Bad request" httpd-error ;

: url>path ( uri -- path )
    url-decode dup "http://" str-head? dup [
        "/" split1 f "" replace nip nip
    ] [
        drop
    ] ifte ;

: secure-path ( path -- path )
    ".." over str-contains? [ drop f ] when ;

: handle-request ( arg cmd -- )
    [
        [ "GET"  = ] [ drop "get"  serve-responder ]
        [ "POST" = ] [ drop "post" serve-responder ]
        [ drop t   ] [ 2drop bad-request           ]
    ] cond ;

: parse-request ( request -- )
    dup log
    " " split1 dup [
        " HTTP" split1 drop url>path secure-path dup [
            swap handle-request
        ] [
            2drop bad-request
        ] ifte
    ] [
        2drop bad-request
    ] ifte ;

: httpd-client ( socket -- )
    [
        "stdio" get "client" set log-client
        read [ parse-request ] when*
    ] with-stream ;

: quit-flag ( -- ? )
    global [ "httpd-quit" get ] bind ;

: clear-quit-flag ( -- )
    global [ "httpd-quit" off ] bind ;

: httpd-loop ( server -- server )
    [
        quit-flag not
    ] [
        dup accept httpd-client
    ] while ;

: httpd ( port -- )
    [
        <server> [
            httpd-loop
        ] [
            swap fclose clear-quit-flag rethrow
        ] catch
    ] with-logging ;