Solution to Project Euler problem 65

extra/project-euler/065/065-tests.factor

@@ -0,0 +1,4 @@
+USING: project-euler.065 tools.test ;
+IN: project-euler.065.tests
+
+[ 272 ] [ euler065 ] unit-test

extra/project-euler/065/065.factor

@@ -0,0 +1,77 @@
+! Copyright (c) 2009 Guillaume Nargeot.
+! See http://factorcode.org/license.txt for BSD license.
+USING: kernel math lists lists.lazy project-euler.common sequences ;
+IN: project-euler.065
+
+! http://projecteuler.net/index.php?section=problems&id=065
+
+! DESCRIPTION
+! -----------
+
+! The square root of 2 can be written as an infinite continued fraction.
+
+!                      1
+! √2 = 1 + -------------------------
+!                        1
+!          2 + ---------------------
+!                          1
+!              2 + -----------------
+!                            1
+!                  2 + -------------
+!                      2 + ...
+
+! The infinite continued fraction can be written, √2 = [1;(2)], (2) indicates
+! that 2 repeats ad infinitum. In a similar way, √23 = [4;(1,3,1,8)].
+
+! It turns out that the sequence of partial values of continued fractions for
+! square roots provide the best rational approximations. Let us consider the
+! convergents for √2.
+
+!     1   3         1     7           1       17             1         41
+! 1 + - = - ; 1 + ----- = - ; 1 + --------- = -- ; 1 + ------------- = --
+!     2   2           1   5             1     12               1       29
+!                 2 + -           2 + -----            2 + ---------
+!                     2                   1                      1  
+!                                     2 + -                2 + -----
+!                                         2                        1
+!                                                              2 + -
+!                                                                  2
+
+! Hence the sequence of the first ten convergents for √2 are:
+! 1, 3/2, 7/5, 17/12, 41/29, 99/70, 239/169, 577/408, 1393/985, 3363/2378, ...
+
+! What is most surprising is that the important mathematical constant,
+! e = [2; 1,2,1, 1,4,1, 1,6,1 , ... , 1,2k,1, ...].
+
+! The first ten terms in the sequence of convergents for e are:
+! 2, 3, 8/3, 11/4, 19/7, 87/32, 106/39, 193/71, 1264/465, 1457/536, ...
+
+! The sum of digits in the numerator of the 10th convergent is 1+4+5+7=17.
+
+! Find the sum of digits in the numerator of the 100th convergent of the
+! continued fraction for e.
+
+
+! SOLUTION
+! --------
+
+<PRIVATE
+
+: (e-frac) ( -- seq )
+    2 lfrom [
+        dup 3 mod zero? [ 3 / 2 * ] [ drop 1 ] if
+    ] lazy-map ;
+
+: e-frac ( n -- n )
+    1 - (e-frac) ltake list>array reverse 0
+    [ + recip ] reduce 2 + ;
+
+PRIVATE>
+
+: euler065 ( -- answer )
+    100 e-frac numerator number>digits sum ;
+
+! [ euler065 ] 100 ave-time
+! 4 ms ave run time - 0.33 SD (100 trials)
+
+SOLUTION: euler065

extra/project-euler/project-euler.factor

@@ -16,15 +16,15 @@ USING: definitions io io.files io.pathnames kernel math math.parser
     project-euler.045 project-euler.046 project-euler.047 project-euler.048
     project-euler.049 project-euler.052 project-euler.053 project-euler.054
     project-euler.055 project-euler.056 project-euler.057 project-euler.058
-    project-euler.059 project-euler.063 project-euler.067 project-euler.069
+    project-euler.059 project-euler.063 project-euler.065 project-euler.067
-    project-euler.071 project-euler.072 project-euler.073 project-euler.074
+    project-euler.069 project-euler.071 project-euler.072 project-euler.073
-    project-euler.075 project-euler.076 project-euler.079 project-euler.085
+    project-euler.074 project-euler.075 project-euler.076 project-euler.079
-    project-euler.092 project-euler.097 project-euler.099 project-euler.100
+    project-euler.085 project-euler.092 project-euler.097 project-euler.099
-    project-euler.102 project-euler.112 project-euler.116 project-euler.117
+    project-euler.100 project-euler.102 project-euler.112 project-euler.116
-    project-euler.124 project-euler.134 project-euler.148 project-euler.150
+    project-euler.117 project-euler.124 project-euler.134 project-euler.148
-    project-euler.151 project-euler.164 project-euler.169 project-euler.173
+    project-euler.150 project-euler.151 project-euler.164 project-euler.169
-    project-euler.175 project-euler.186 project-euler.190 project-euler.203
+    project-euler.173 project-euler.175 project-euler.186 project-euler.190
-    project-euler.215 ;
+    project-euler.203 project-euler.215 ;
 IN: project-euler
 
 <PRIVATE