Solution to Project Euler problem 188

extra/project-euler/188/188-tests.factor

@@ -0,0 +1,4 @@
+USING: project-euler.188 tools.test ;
+IN: project-euler.188.tests
+
+[ 95962097 ] [ euler188 ] unit-test

extra/project-euler/188/188.factor

@@ -0,0 +1,43 @@
+! Copyright (c) 2009 Guillaume Nargeot.
+! See http://factorcode.org/license.txt for BSD license.
+USING: kernel math math.functions project-euler.common ;
+IN: project-euler.188
+
+! http://projecteuler.net/index.php?section=problems&id=188
+
+! DESCRIPTION
+! -----------
+
+! The hyperexponentiation or tetration of a number a by a positive integer b,
+! denoted by a↑↑b or ^(b)a, is recursively defined by:
+
+! a↑↑1 = a,
+! a↑↑(k+1) = a^(a↑↑k).
+
+! Thus we have e.g. 3↑↑2 = 3^3 = 27, hence
+! 3↑↑3 = 3^27 = 7625597484987 and
+! 3↑↑4 is roughly 10^(3.6383346400240996*10^12).
+
+! Find the last 8 digits of 1777↑↑1855.
+
+
+! SOLUTION
+! --------
+
+! Using modular exponentiation.
+! http://en.wikipedia.org/wiki/Modular_exponentiation
+
+<PRIVATE
+
+: hyper-exp-mod ( a b m -- e )
+    1 rot [ [ 2dup ] dip swap ^mod ] times 2nip ;
+
+PRIVATE>
+
+: euler188 ( -- answer )
+    1777 1855 10 8 ^ hyper-exp-mod ;
+
+! [ euler188 ] 100 ave-time
+! 4 ms ave run time - 0.05 SD (100 trials)
+
+SOLUTION: euler188

extra/project-euler/project-euler.factor

@@ -24,7 +24,7 @@ USING: definitions io io.files io.pathnames kernel math math.parser
     project-euler.116 project-euler.117 project-euler.124 project-euler.134
     project-euler.148 project-euler.150 project-euler.151 project-euler.164
     project-euler.169 project-euler.173 project-euler.175 project-euler.186
-    project-euler.190 project-euler.203 project-euler.215 ;
+    project-euler.188 project-euler.190 project-euler.203 project-euler.215 ;
 IN: project-euler
 
 <PRIVATE