diff --git a/basis/struct-arrays/authors.txt b/basis/struct-arrays/authors.txt
new file mode 100644
index 0000000000..1901f27a24
--- /dev/null
+++ b/basis/struct-arrays/authors.txt
@@ -0,0 +1 @@
+Slava Pestov
diff --git a/basis/struct-arrays/struct-arrays-tests.factor b/basis/struct-arrays/struct-arrays-tests.factor
new file mode 100644
index 0000000000..160abfe90a
--- /dev/null
+++ b/basis/struct-arrays/struct-arrays-tests.factor
@@ -0,0 +1,19 @@
+IN: struct-arrays.tests
+USING: struct-arrays tools.test kernel math sequences
+alien.syntax alien.c-types ;
+
+C-STRUCT: test-struct
+{ "int" "x" }
+{ "int" "y" } ;
+
+: make-point ( x y -- struct )
+    "test-struct" <c-object>
+    [ set-test-struct-y ] keep
+    [ set-test-struct-x ] keep ;
+
+[ 5/4 ] [
+    2 "test-struct" <struct-array>
+    1 2 make-point over set-first
+    3 4 make-point over set-second
+    0 [ [ test-struct-x ] [ test-struct-y ] bi / + ] reduce
+] unit-test
diff --git a/basis/struct-arrays/struct-arrays.factor b/basis/struct-arrays/struct-arrays.factor
new file mode 100644
index 0000000000..0b31845fc7
--- /dev/null
+++ b/basis/struct-arrays/struct-arrays.factor
@@ -0,0 +1,37 @@
+! Copyright (C) 2008 Slava Pestov.
+! See http://factorcode.org/license.txt for BSD license.
+USING: accessors alien alien.c-types byte-arrays kernel libc
+math sequences sequences.private ;
+IN: struct-arrays
+
+TUPLE: struct-array
+{ underlying c-ptr read-only }
+{ length array-capacity read-only }
+{ element-size array-capacity read-only } ;
+
+M: struct-array length length>> ;
+
+M: struct-array nth-unsafe
+    [ element-size>> * ] [ underlying>> ] bi <displaced-alien> ;
+
+M: struct-array set-nth-unsafe
+    [ nth-unsafe swap ] [ element-size>> ] bi memcpy ;
+
+M: struct-array new-sequence
+    element-size>> [ * <byte-array> ] 2keep struct-array boa ; inline
+
+: <struct-array> ( length c-type -- struct-array )
+    heap-size [ * <byte-array> ] 2keep struct-array boa ; inline
+
+ERROR: bad-byte-array-length byte-array ;
+
+: byte-array>struct-array ( byte-array c-type -- struct-array )
+    heap-size [
+        [ dup length ] dip /mod 0 =
+        [ drop bad-byte-array-length ] unless
+    ] keep struct-array boa ; inline
+
+: <direct-struct-array> ( alien length c-type -- struct-array )
+    struct-array boa ; inline
+
+INSTANCE: struct-array sequence
diff --git a/basis/struct-arrays/summary.txt b/basis/struct-arrays/summary.txt
new file mode 100644
index 0000000000..0458b5a806
--- /dev/null
+++ b/basis/struct-arrays/summary.txt
@@ -0,0 +1 @@
+Arrays of C structs and unions
diff --git a/basis/struct-arrays/tags.txt b/basis/struct-arrays/tags.txt
new file mode 100644
index 0000000000..42d711b32b
--- /dev/null
+++ b/basis/struct-arrays/tags.txt
@@ -0,0 +1 @@
+collections