diff --git a/extra/base32/base32-tests.factor b/extra/base32/base32-tests.factor
new file mode 100644
index 0000000000..c77d0f2147
--- /dev/null
+++ b/extra/base32/base32-tests.factor
@@ -0,0 +1,20 @@
+! Copyright (C) 2019 John Benediktsson
+! See http://factorcode.org/license.txt for BSD license
+
+USING: base32 tools.test ;
+
+{ "16J" } [ 1234 base32> ] unit-test
+{ "16JD" } [ 1234 base32-checksum> ] unit-test
+{ "0" } [ 0 base32> ] unit-test
+{ "00" } [ 0 base32-checksum> ] unit-test
+[ -1 base32> ] must-fail
+[ 1.0 base32> ] must-fail
+
+{ 1234 } [ "16J" >base32 ] unit-test
+{ 1234 } [ "I6J" >base32 ] unit-test
+{ 1234 } [ "i6J" >base32 ] unit-test
+{ 1234 } [ "16JD" >base32-checksum ] unit-test
+{ 1234 } [ "I6JD" >base32-checksum ] unit-test
+{ 1234 } [ "i6JD" >base32-checksum ] unit-test
+{ 0 } [ "0" >base32 ] unit-test
+{ 0 } [ "00" >base32-checksum ] unit-test
diff --git a/extra/base32/base32.factor b/extra/base32/base32.factor
new file mode 100644
index 0000000000..700b58e58f
--- /dev/null
+++ b/extra/base32/base32.factor
@@ -0,0 +1,41 @@
+! Copyright (C) 2019 John Benediktsson
+! See http://factorcode.org/license.txt for BSD license
+
+USING: ascii assocs kernel literals math sequences ;
+
+IN: base32
+
+<PRIVATE
+
+<<
+CONSTANT: ALPHABET "0123456789ABCDEFGHJKMNPQRSTVWXYZ"
+>>
+CONSTANT: CHECKSUM $[ ALPHABET "*~$=U" append ]
+
+: normalize-base32 ( seq -- seq' )
+    CHAR: - swap remove >upper H{
+        { CHAR: I CHAR: 1 }
+        { CHAR: L CHAR: 1 }
+        { CHAR: O CHAR: 0 }
+    } substitute ;
+
+: parse-base32 ( seq -- base32 )
+    0 swap [ [ 32 * ] [ ALPHABET index + ] bi* ] each ;
+
+PRIVATE>
+
+: >base32 ( seq -- base32 )
+    normalize-base32 parse-base32 ;
+
+: base32> ( base32 -- seq )
+    dup 0 < [ non-negative-integer-expected ] when
+    [ dup 0 > ] [
+        32 /mod ALPHABET nth
+    ] "" produce-as nip [ "0" ] when-empty reverse! ;
+
+: >base32-checksum ( seq -- base32 )
+    normalize-base32 unclip-last [ parse-base32 ] dip
+    CHECKSUM index over 37 mod assert= ;
+
+: base32-checksum> ( base32 -- seq )
+    [ base32> ] keep 37 mod CHECKSUM nth suffix ;
diff --git a/extra/base32/summary.txt b/extra/base32/summary.txt
new file mode 100644
index 0000000000..97327ad820
--- /dev/null
+++ b/extra/base32/summary.txt
@@ -0,0 +1 @@
+Douglas Crockford's Base 32 encoding/decoding