! Copyright (C) 2005 Slava Pestov.
! See http://factor.sf.net/license.txt for BSD license.
IN: gadgets
USING: generic hashtables inspector io jedit kernel lists memory
namespaces parser prettyprint sequences styles vectors words ;

SYMBOL: commands

{ } clone commands global set-hash

: define-command ( class name quot -- )
    3vector commands get push ;

: applicable ( object -- seq )
    commands get [ first call ] subset-with ;

: command-quot ( presented quot -- quot )
    [ swap literalize , % ] [ ] make
    [ pane get pane-call drop ] cons ;

: command-menu ( presented -- menu )
    dup applicable
    [ [ third command-quot ] keep second swons ] map-with
    <menu> ;

: init-commands ( gadget -- )
    dup presented paint-prop dup [
        [
            \ drop ,
            literalize ,
            [ command-menu show-menu ] %
        ] [ ] make
        button-gestures
    ] [
        2drop
    ] ifte ;

: <styled-label> ( style text -- label )
    <label> swap dup [ alist>hash ] when over set-gadget-paint ;

: <presentation> ( style text -- presentation )
    gadget pick assoc dup
    [ 2nip ] [ drop <styled-label> dup init-commands ] ifte ;

: gadget. ( gadget -- )
    gadget swons unit
    "This stream does not support live gadgets"
    swap format terpri ;

[ drop t ] "Prettyprint" [ . ] define-command
[ drop t ] "Inspect" [ inspect ] define-command
[ drop t ] "References" [ references inspect ] define-command

[ word? ] "See" [ see ] define-command
[ word? ] "Usage" [ usage . ] define-command
[ word? ] "jEdit" [ jedit ] define-command

[ [ gadget? ] is? ] "Display" [ gadget. ] define-command