55 lines
1.6 KiB
Factor
55 lines
1.6 KiB
Factor
! Copyright (C) 2012 John Benediktsson, Doug Coleman
|
|
! See http://factorcode.org/license.txt for BSD license
|
|
|
|
USING: arrays assocs assocs.private kernel math sequences ;
|
|
|
|
IN: assocs.extras
|
|
|
|
: assoc-sift ( assoc -- assoc' )
|
|
[ nip ] assoc-filter ; inline
|
|
|
|
: assoc-harvest ( assoc -- assoc' )
|
|
[ nip empty? not ] assoc-filter ; inline
|
|
|
|
: deep-at ( assoc seq -- value/f )
|
|
[ of ] each ; inline
|
|
|
|
: zip-as ( keys values exemplar -- assoc )
|
|
dup sequence? [
|
|
[ 2array ] swap 2map-as
|
|
] [
|
|
[ 2dup min-length ] dip new-assoc
|
|
[ [ set-at ] with-assoc 2each ] keep
|
|
] if ; inline
|
|
|
|
: substitute! ( seq assoc -- seq )
|
|
substituter map! ;
|
|
|
|
: assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
|
|
[ >alist ] 2dip [ first2 ] prepose reduce ; inline
|
|
|
|
: reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
|
|
[ drop ] prepose assoc-reduce ; inline
|
|
|
|
: reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
|
|
[ nip ] prepose assoc-reduce ; inline
|
|
|
|
: sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
|
|
|
|
: sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
|
|
|
|
: if-assoc-empty ( ..a assoc quot1: ( ..a -- ..b ) quot2: ( ..a assoc -- ..b ) -- ..b )
|
|
[ dup assoc-empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
|
|
|
|
: assoc-invert-as ( assoc exemplar -- newassoc )
|
|
[ swap ] swap assoc-map-as ;
|
|
|
|
: assoc-invert ( assoc -- newassoc )
|
|
dup assoc-invert-as ;
|
|
|
|
: (assoc-merge) ( assoc1 assoc2 -- assoc1 )
|
|
over [ push-at ] with-assoc assoc-each ;
|
|
|
|
: assoc-merge ( seq -- merge )
|
|
H{ } clone [ (assoc-merge) ] reduce ;
|