101 lines
2.3 KiB
Factor
101 lines
2.3 KiB
Factor
! Copyright (C) 2005, 2009 Slava Pestov.
|
|
! See http://factorcode.org/license.txt for BSD license.
|
|
USING: accessors arrays hashtables io kernel math math.functions
|
|
namespaces make opengl sequences strings splitting ui.gadgets
|
|
ui.gadgets.tracks ui.gadgets.packs fonts ui.render ui.pens.solid
|
|
ui.text colors colors.constants models combinators ;
|
|
IN: ui.gadgets.labels
|
|
|
|
! A label gadget draws a string.
|
|
TUPLE: label < gadget text font ;
|
|
|
|
SLOT: string
|
|
|
|
M: label string>> ( label -- string )
|
|
text>> dup string? [ "\n" join ] unless ; inline
|
|
|
|
<PRIVATE
|
|
|
|
PREDICATE: string-array < array [ string? ] all? ;
|
|
|
|
PRIVATE>
|
|
|
|
: ?string-lines ( string -- string/array )
|
|
CHAR: \n over memq? [ string-lines ] when ;
|
|
|
|
ERROR: not-a-string object ;
|
|
|
|
M: label (>>string) ( string label -- )
|
|
[
|
|
{
|
|
{ [ dup string-array? ] [ ] }
|
|
{ [ dup string? ] [ ?string-lines ] }
|
|
[ not-a-string ]
|
|
} cond
|
|
] dip (>>text) ; inline
|
|
|
|
: label-theme ( gadget -- gadget )
|
|
sans-serif-font >>font ; inline
|
|
|
|
: new-label ( string class -- label )
|
|
new-gadget
|
|
swap >>string
|
|
label-theme ; inline
|
|
|
|
: <label> ( string -- label )
|
|
label new-label ;
|
|
|
|
: >label< ( label -- font text )
|
|
[ font>> ] [ text>> ] bi ;
|
|
|
|
M: label pref-dim*
|
|
>label< text-dim ;
|
|
|
|
M: label baseline
|
|
>label< dup string? [ first ] unless
|
|
line-metrics ascent>> round ;
|
|
|
|
M: label draw-gadget* >label< draw-text ;
|
|
|
|
M: label gadget-text* string>> % ;
|
|
|
|
TUPLE: label-control < label ;
|
|
|
|
M: label-control model-changed
|
|
swap value>> >>string relayout ;
|
|
|
|
: <label-control> ( model -- gadget )
|
|
"" label-control new-label
|
|
swap >>model ;
|
|
|
|
: text-theme ( gadget -- gadget )
|
|
monospace-font >>font ;
|
|
|
|
: reverse-video-theme ( label -- label )
|
|
sans-serif-font reverse-video-font >>font
|
|
COLOR: black <solid> >>interior ;
|
|
|
|
GENERIC: >label ( obj -- gadget )
|
|
M: string >label <label> ;
|
|
M: array >label <label> ;
|
|
M: object >label ;
|
|
M: f >label drop <gadget> ;
|
|
|
|
<PRIVATE
|
|
|
|
: label-on-left/right ( -- track )
|
|
horizontal <track>
|
|
+baseline+ >>align
|
|
{ 5 5 } >>gap ; inline
|
|
PRIVATE>
|
|
|
|
: label-on-left ( gadget label -- button )
|
|
label-on-left/right
|
|
swap >label f track-add
|
|
swap 1 track-add ;
|
|
|
|
: label-on-right ( label gadget -- button )
|
|
label-on-left/right
|
|
swap f track-add
|
|
swap >label 1 track-add ;
|