factor/basis/math/statistics/statistics.factor

! Copyright (C) 2008 Doug Coleman, Michael Judge.
! See http://factorcode.org/license.txt for BSD license.
USING: assocs combinators generalizations kernel locals math
math.functions math.order math.vectors sequences
sequences.private sorting fry ;
IN: math.statistics

: mean ( seq -- x )
    [ sum ] [ length ] bi / ;

: geometric-mean ( seq -- x )
    [ length ] [ product ] bi nth-root ;

: harmonic-mean ( seq -- x )
    [ recip ] map-sum recip ;

<PRIVATE

:: (kth-object) ( seq k quot: ( x y -- ? ) nth-quot exchange-quot -- elt )
    #! Wirth's method, Algorithm's + Data structues = Programs p. 84
    #! The algorithm modifiers seq, so we clone it
    k seq bounds-check 2drop
    seq clone :> seq
    0 :> i!
    0 :> j!
    0 :> l!
    0 :> x!
    seq length 1 - :> m!
    [ l m < ]
    [
        k seq nth x!
        l i!
        m j!
        [ i j <= ]
        [
            [ i seq nth-quot call x quot call ] [ i 1 + i! ] while
            [ x j seq nth-quot call quot call ] [ j 1 - j! ] while
            i j <= [
                i j seq exchange-quot call
                i 1 + i!
                j 1 - j!
            ] when
        ] do while

        j k < [ i l! ] when
        k i < [ j m! ] when
    ] while
    k seq nth ; inline

: kth-object-unsafe ( seq k quot: ( x y -- ? ) -- elt )
    [ nth-unsafe ] [ exchange-unsafe ] (kth-object) ; inline

PRIVATE>

: kth-object ( seq k quot: ( x y -- ? ) -- elt )
    [ nth ] [ exchange ] (kth-object) ; inline

: kth-smallest ( seq k -- elt ) [ < ] kth-object-unsafe ;
    
: kth-largest ( seq k -- elt ) [ > ] kth-object-unsafe ;

: count-relative ( seq k -- lt eq gt )
    [ 0 0 0 ] 2dip '[
        _ <=> {
            { +lt+ [ [ 1 + ] 2dip ] }
            { +gt+ [ 1 + ] }
            { +eq+ [ [ 1 + ] dip ] }
        } case
    ] each ;

: minmax-relative ( seq k -- lt eq gt lt-max gt-min )
    [ 0 0 0 -1/0. 1/0. ] 2dip '[
        dup _ <=> {
            { +lt+ [ [ 1 + ] 5 ndip '[ _ max ] dip ] }
            { +gt+ [ [ 1 + ] 3dip min ] }
            { +eq+ [ [ 1 + ] 4dip drop ] }
        } case
    ] each ;
    
: lower-median ( seq -- elt )
    [ ] [ ] [ length odd? ] tri
    [ midpoint@ ] [ midpoint@ 1 - ] if kth-smallest ;

: upper-median ( seq -- elt )
    dup midpoint@ kth-smallest ;

: medians ( seq -- lower upper )
    [ lower-median ] [ upper-median ] bi ;

: median ( seq -- x )
    [ ] [ length odd? ] bi [ lower-median ] [ medians + 2 / ] if ;

<PRIVATE

: (sequence>assoc) ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) assoc -- assoc )
    [ swap curry compose each ] keep ; inline

PRIVATE>

: sequence>assoc! ( assoc seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- assoc )
    4 nrot (sequence>assoc) ; inline

: sequence>assoc ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) exemplar -- assoc )
    clone (sequence>assoc) ; inline

: sequence>hashtable ( seq map-quot: ( x -- ..y ) insert-quot: ( ..y assoc -- ) -- hashtable )
    H{ } sequence>assoc ; inline

: histogram! ( hashtable seq -- hashtable )
    [ ] [ inc-at ] sequence>assoc! ;

: histogram-by ( seq quot: ( x -- bin ) -- hashtable )
    [ inc-at ] sequence>hashtable ; inline

: histogram ( seq -- hashtable )
    [ ] histogram-by ;

: sorted-histogram ( seq -- alist )
    histogram sort-values ;

: collect-pairs ( seq quot: ( x -- v k ) -- hashtable )
    [ push-at ] sequence>hashtable ; inline

: collect-by ( seq quot: ( x -- x' ) -- hashtable )
    [ dup ] prepose collect-pairs ; inline

: mode ( seq -- x )
    histogram >alist
    [ ] [ [ [ second ] bi@ > ] most ] map-reduce first ;

ERROR: empty-sequence ;

: minmax ( seq -- min max )
    [
        empty-sequence
    ] [
        [ first dup ] keep [ [ min ] [ max ] bi-curry bi* ] each
    ] if-empty ;

: range ( seq -- x )
    minmax swap - ;

: sample-var ( seq -- x )
    #! normalize by N-1
    dup length 1 <= [
        drop 0
    ] [
        [ [ mean ] keep [ - sq ] with map-sum ]
        [ length 1 - ] bi /
    ] if ;

: var ( seq -- x )
    dup length 1 <= [
        drop 0
    ] [
        [ [ mean ] keep [ - sq ] with map-sum ]
        [ length ] bi /
    ] if ;

: std ( seq -- x ) var sqrt ;

: ste ( seq -- x ) [ std ] [ length ] bi sqrt / ;

: ((r)) ( mean(x) mean(y) {x} {y} -- (r) )
    ! finds sigma((xi-mean(x))(yi-mean(y))
    0 [ [ [ pick ] dip swap - ] bi@ * + ] 2reduce 2nip ;

: (r) ( mean(x) mean(y) {x} {y} sx sy -- r )
    * recip [ [ ((r)) ] keep length 1 - / ] dip * ;

: [r] ( {{x,y}...} -- mean(x) mean(y) {x} {y} sx sy )
    first2 [ [ [ mean ] bi@ ] 2keep ] 2keep [ std ] bi@ ;

: r ( {{x,y}...} -- r )
    [r] (r) ;

: r^2 ( {{x,y}...} -- r )
    r sq ;

: least-squares ( {{x,y}...} -- alpha beta )
    [r] { [ 2dup ] [ ] [ ] [ ] [ ] } spread
    ! stack is mean(x) mean(y) mean(x) mean(y) {x} {y} sx sy
    [ (r) ] 2keep ! stack is mean(x) mean(y) r sx sy
    swap / * ! stack is mean(x) mean(y) beta
    [ swapd * - ] keep ;

: cov ( {x} {y} -- cov )
    [ dup mean v-n ] bi@ v* mean ;

: corr ( {x} {y} -- corr )
     [ cov ] [ [ var ] bi@ * sqrt ] 2bi / ;

: cum-sum ( seq -- seq' )
    0 swap [ + dup ] map nip ;

: cum-product ( seq -- seq' )
    1 swap [ * dup ] map nip ;

: cum-min ( seq -- seq' )
    [ ?first ] keep [ min dup ] map nip ;

: cum-max ( seq -- seq' )
    [ ?first ] keep [ max dup ] map nip ;